What is on an Excel assessment test?

Cell references, Everyday math, Conditional math, Logic, Lookups, Data tools, Text and dates.

How can I practise for an Excel test?

Read the question twice. Tests love “greater than” vs “at least”: >5 and >=5 give different answers. Use whole-column ranges carefully. Stick to the data range (B2:B9) unless the question says otherwise. Exact match, always: end VLOOKUP with FALSE and MATCH with 0. Watch the clock. Skip a question that’s eating time and come back to it. Check your answer makes sense: a “total” smaller than one of its parts means a wrong range.

Interview prep

Excel test practice: free questions with answers

Many employers ask candidates to take a short Excel skills test, often timed and done in a real or simulated spreadsheet. The good news: most tests cover the same core skills. Practise these and you’ll recognise almost every question.

Take a timed practice test 12 questions, 12 minutes, scored like the real thing.

What Excel tests usually cover

Cell references

Relative vs absolute ($A$1) references, and why a copied formula “breaks”.

Everyday math

SUM, AVERAGE, MIN, MAX, COUNT and percentages of a total.

Conditional math

COUNTIF, SUMIF and their multi-condition versions COUNTIFS and SUMIFS.

Logic

IF, nested IF or IFS, and combining tests with AND and OR.

Lookups

VLOOKUP with an exact match, XLOOKUP, and INDEX with MATCH.

Data tools

Sorting, filtering, conditional formatting, PivotTables and charts.

Text and dates

TRIM, LEFT/RIGHT, CONCAT, TEXT, and date functions like EOMONTH.

12 sample questions

Answer each on the table, then reveal the formula.

	A	B	C	D	E	F
1	Order	Region	Rep	Units	Price	Revenue
2	5601	West	Maya	6	9	54
3	5602	West	Raj	4	45	180
4	5603	South	Omar	2	60	120
5	5604	South	Maya	2	30	60
6	5605	North	Theo	3	9	27
7	5606	South	Raj	1	24	24
8	5607	South	Maya	8	24	192
9	5608	North	Raj	8	15	120

How many orders came from South?
Show answer
=COUNTIF(B2:B9,"South") → 4
List every Rep once. Your formula spills down from H2.
Show answer
=UNIQUE(C2:C9) → Maya, Raj, Omar, Theo
Use INDEX and MATCH to return the Units for order 5605.
Show answer
=INDEX(D2:D9,MATCH(5605,A2:A9,0)) → 3
Find the largest Units on any order.
Show answer
=MAX(D2:D9) → 8
Return "Yes" if order 5601 is from West and sold more than 5 units, otherwise "No".
Show answer
=IF(AND(B2="West",D2>5),"Yes","No") → Yes
Use XLOOKUP to find the Region for order 5607.
Show answer
=XLOOKUP(5607,A2:A9,B2:B9) → South
Find the smallest Revenue on any order.
Show answer
=MIN(F2:F9) → 24
Label order 5605: "Large" if Revenue is at least 100, "Medium" if at least 50, otherwise "Small".
Show answer
=IFS(F6>=100,"Large",F6>=50,"Medium",TRUE,"Small") → Small
Total Revenue from South orders.
Show answer
=SUMIF(B2:B9,"South",F2:F9) → 396
Order 5619 doesn’t exist. Look up its Price with VLOOKUP, but show "Not found" instead of an error.
Show answer
=IFERROR(VLOOKUP(5619,A2:F9,5,FALSE),"Not found") → Not found
Find the largest Revenue among South orders.
Show answer
=MAXIFS(F2:F9,B2:B9,"South") → 192
Average Revenue on orders sold by Raj.
Show answer
=AVERAGEIFS(F2:F9,C2:C9,"Raj") → 108

Tips for test day

Read the question twice. Tests love “greater than” vs “at least”: >5 and >=5 give different answers.
Use whole-column ranges carefully. Stick to the data range (B2:B9) unless the question says otherwise.
Exact match, always: end VLOOKUP with FALSE and MATCH with 0.
Watch the clock. Skip a question that’s eating time and come back to it.
Check your answer makes sense: a “total” smaller than one of its parts means a wrong range.